Home > Articles

  • Print
  • + Share This
This chapter is from the book

VBA Techniques

So far, we've concentrated on the techniques we can use to get the most out of Excel's charting engine through the user interface. In this section, we examine how we can use VBA to manipulate charts.

Converting Between Chart Coordinate Systems

When using VBA to work with charts, there are (at least) four different coordinate systems that we often need to convert between:

  • The chart series data displayed inside the plot area is in the axis coordinates if it's an XY Scatter chart.
  • The mouse pointer coordinates given in the MouseMove etc. events are measured in pixels, with the origin in the top-left corner of the ChartObject window.
  • The coordinates of any drawing objects added to the chart are in points, with the origin being the top left of the chart area, slightly inside the ChartObject window.
  • The coordinates used by the GET.CHART.ITEM XLM function to locate the vertices of chart objects are in points, but with the origin in the bottom-left corner of the chart area. See the Locating Chart Items section later for an example of its use.

Furthermore, if the chart is embedded on a worksheet, the worksheet zoom factor affects the mouse pointer coordinates, but not the data nor location of any drawing objects on the chart.

Listing 15-2 shows a MouseMove event for a chart, within which we convert the X, Y mouse coordinates given to the event into both data coordinates (displayed in the status bar) and drawing object coordinates (which we use to move an oval to follow the mouse pointer). Note that this code uses the PointsPerPixel function defined in Chapter 9 &8212; Understanding and Using Windows API Calls:

Example 15-2. Converting from Mouse Coordinates to Data and Drawing Object Coordinates

Private Sub mchtChart_MouseMove(ByVal Button As Long, _
    ByVal Shift As Long, ByVal X As Long, ByVal Y As Long)

  Dim dZoom As Double
  Dim dXVal As Double
  Dim dYVal As Double
  Dim dPixelSize As Double

  On Error Resume Next

  'The active window zoom factor
  dZoom = ActiveWindow.Zoom / 100

  'The pixel size, in points
  dPixelSize = PointsPerPixel

  'Mouse coordinates to (XY) Data coordinates
  With mchtChart
    dXVal = .Axes(xlCategory).MinimumScale + _
      (.Axes(xlCategory).MaximumScale - _
       .Axes(xlCategory).MinimumScale) * _
      (X * dPixelSize / dZoom - _
       (.PlotArea.InsideLeft + .ChartArea.Left)) / _
      .PlotArea.InsideWidth

    dYVal = .Axes(xlValue).MinimumScale + _
      (.Axes(xlValue).MaximumScale - _
       .Axes(xlValue).MinimumScale) * _
      (1 - (Y * dPixelSize / dZoom - _
            (.PlotArea.InsideTop + .ChartArea.Top)) / _
      .PlotArea.InsideHeight)
  End With

  Application.StatusBar = "(" & Application.Round(dXVal, 2) _
      & ", " & Application.Round(dYVal, 2) & ")"

  'Mouse coordinates to Drawing Object Points

  'We'll only move the oval if the Shift key is pressed
  If Shift = 1 Then
    With mchtChart
      dXVal = (X * dPixelSize / dZoom - .ChartArea.Left)
      dYVal = (Y * dPixelSize / dZoom - .ChartArea.Top)

      With .Shapes("ovlPointer")
        .Left = dXVal - .Width / 2
        .Top = dYVal - .Height / 2
      End With
    End With
  End If

End Sub

Locating Chart Items

Sometimes, however hard we try, the only way to get a chart looking exactly how we want it is to add drawing objects to it, such as rectangles, lines, arrows and so on. As soon as we do that, we hit the problem of trying to identify where in the drawing object coordinate space an item on the chart is located, such as the top middle of a specific column in a column chart.

That level of positional information cannot be obtained through the Excel object model, but can be obtained by calling on the long-disused XLM function GET.CHART.ITEM. This function has the following parameters:

GET.CHART.ITEM(x_y_index, point_index, item_text)

Where:

  • x_y_index is 1 to return the x position and 2 to return the y position.
  • point_index depends on the item we're looking at, but is a number from 1 to 8 to identify a specific vertex within the item. For example, 2 is the upper middle of any rectangular item, such as a column in a column chart.
  • item_text identifies the item we're interested in, such as "Plot" for the plot area, or "S2P4" for the fourth data point in the second series in the chart.

The full list of available parameters can be found in the XLM Macros help file available for download from the Microsoft Web site at http://support.microsoft.com/?kbid=128175. The only caveat with using GET.CHART.ITEM is that the chart must be active for it to work. The code in Listing 15-3 moves an arrow on a chart to be from the top-left corner of the inside of the plot area (using normal VBA positioning) to the top middle of the third column of a column chart, resulting in the chart shown in Figure 15-16.

Example 15-3. Using GET.CHART.ITEM to Locate a Chart Item's Vertices

Private Sub cmdMoveArrow_Click()

  Dim rngActive As Range
  Dim dXVal As Double
  Dim dYVal As Double
  Dim chtChart As Chart

  Set rngActive = ActiveCell

  'We have to activate the chart to use GET.CHART.ITEM
  Me.ChartObjects(1).Activate

  'Find the XY position of the middle top of the third column 
  'in the data series,
  'returned in XLM coordinates
  dXVal = ExecuteExcel4Macro("GET.CHART.ITEM(1,2,""S1P3"")")
  dYVal = ExecuteExcel4Macro("GET.CHART.ITEM(2,2,""S1P3"")")

  'Get the Chart
  Set chtChart = Me.ChartObjects(1).Chart
  With chtChart

    'Convert the XLM coordinates to Drawing Object coordinates
    'The x values are the same, but the Y values need to be 
    'flipped
    dYVal = .ChartArea.Height - dYVal

    'Move and size the Arrow
    .Shapes("linArrow").Left = .PlotArea.InsideLeft
    .Shapes("linArrow").Top = .PlotArea.InsideTop
    .Shapes("linArrow").Width = dXVal - .Shapes("linArrow").Left
    .Shapes("linArrow").Height = dYVal - .Shapes("linArrow").Top
  End With

  rngActive.Activate

End Sub
15fig16.gif"

Figure 15-16 Moving an Arrow to Point to the Top Middle of a Column

Calculating Reasonable Axis Scales

Often when we're controlling charts through VBA, we need to set our own values for the axis scales. The code in Listing 15-4 calculates tidy Minimum, Maximum and MajorUnit values. It is a different algorithm than the one Excel uses to determine chart axis scales, but is one that we have found to give pleasant-looking results.

Example 15-4. Function to Calculate Reasonable Chart Axes Scales

Public Type CHART_SCALE
  dMin As Double
  dMax As Double
  dScale As Double
End Type

Public Function ChartScale(ByVal dMin As Double, _
        ByVal dMax As Double) As CHART_SCALE

    Dim dPower As Double, dScale As Double

    'Check if the max and min are the same
    If dMax = dMin Then
        dScale = dMax
        dMax = dMax * 1.01
        dMin = dMin * 0.99
    End If

    'Check if dMax is bigger than dMin - swap them if not
    If dMax < dMin Then
        dScale = dMax
        dMax = dMin
        dMin = dScale
    End If

    'Make dMax a little bigger and dMin a little smaller
    If dMax > 0 Then
        dMax = dMax + (dMax - dMin) * 0.01
    Else
        dMax = dMax - (dMax - dMin) * 0.01
    End If
    If dMin > 0 Then
        dMin = dMin - (dMax - dMin) * 0.01
    Else
        dMin = dMin + (dMax - dMin) * 0.01
    End If

    'What if they are both 0?
    If (dMax = 0) And (dMin = 0) Then dMax = 1

    'This bit rounds the maximum and minimum values to
    'reasonable values to chart.
    'Find the range of values covered
    dPower = Log(dMax - dMin) / Log(10)
    dScale = 10 ^ (dPower - Int(dPower))

    'Find the scaling factor
    Select Case dScale
    Case 0 To 2.5
        dScale = 0.2
    Case 2.5 To 5
        dScale = 0.5
    Case 5 To 7.5
        dScale = 1
    Case Else
        dScale = 2
    End Select

    'Calculate the scaling factor (major unit)
    dScale = dScale * 10 ^ Int(dPower)

    'Round the axis values to the nearest scaling factor
    ChartScale.dMin = dScale * Int(dMin / dScale)
    ChartScale.dMax = dScale * (Int(dMax / dScale) + 1)
    ChartScale.dScale = dScale

End Function
  • + Share This
  • 🔖 Save To Your Account