Home > Articles > Programming > Windows Programming

  • Print
  • + Share This
This chapter is from the book

Sample Application: Calculating a Future Value

Now that you have explored creating and using variables and procedures, you can create an application that performs an investment calculation. This application will enable you to explore the lovely benefits of regular investing and compound interest. This sample Console application will avoid the complexity that a graphical user interface would add. Listing 3.4 shows the output from one run of the program.

Listing 3.4 The Investment Calculator

 1 InvestCalc.exe
 2 Initial Balance: 10000
 3 Annual Interest (e.g. for 5%, enter 5): 5
 4 Monthly Deposit: 200
 5 Years of Investment: 30
 6
 7 If you start with $10,000.00,
 8    and invest $200.00 per month
 9        for 30 years
10        at 5% interest.
11 Your final balance would be: $211,129.17

Here we see the result of starting with a $10,000 balance and adding $200 per month for 30 years, at a constant 5 percent interest.

The program requires the user to enter the four values (Initial Balance, Annual Interest, Monthly Deposit, and Years of Investment). In turn, the program calculates the final balance. This calculation is known as the Future Value (FV) calculation, and Visual Basic .NET includes it as one of its built-in functions. The formula for Future Value is

FV = MonthlyDeposit * (((1 + MonthlyInterest)^Months - 1 ) 
 / MonthlyInterest ) + StartingBalance * ( 1 + MonthlyInterest )^Months

The following steps outline this procedure so that you can better understand how it works:

  1. Begin by creating a new project in Visual Basic .NET. Select a new Visual Basic Console Application. Visual Basic .NET creates a new project with one module.

  2. Close the file window and rename the file using the Solution Explorer. Right-click on the filename Module1.vb in the Solution Explorer and select Rename. Change the filename to modInvest.vb.

  3. Change the name of the Startup Object, also. Right-click on the project in the Solution Explorer and select Properties. On the General page, change the Startup Object to Invest. This should be in the drop-down list.

  4. You're ready to begin coding. As a minimum, you need four variables to hold the user's input. Declare the variables as shown in Listing 3.5. Most of these values are floating point numbers, with the exception of Years. These declarations should occur between the Module line and the Sub Main() line because these will be Module-level variables.

  5. Listing 3.5 Declarations for the Future Value Calculation

    1 Private dblAnnualInterest As Double = 0
    2 Private iYears As Integer = 0
    3 Private decStartingBalance As Double = 0
    4 Private decMonthlyDeposit As Double = 0
  6. Use the Main routine to call each of the routines that will get the user input, do the calculations, and display the output, as in Listing 3.6.

  7. Listing 3.6 Main Routine

     1 Shared Sub Main()
     2   Dim decResult As Double
     3   'get input values
     4   GetInputValues()
     5   'calculate
     6   decResult = CalculateFV(dblAnnualInterest, _
     7    iYears, _
     8    decMonthlyDeposit, _
     9    decStartingBalance)
    10   'output result
    11   DisplayResults(decResult)
    12 End Sub

    In Listing 3.7, each of the major functions of the application is a separate subroutine or function. This enables you to more easily change the techniques for getting input or display output later.

  8. Add the code in Listing 3.7 to allow the user to enter information. The procedure does not take any parameters, nor does it return a value. Because this is a Console application, you'll use the Console.Read routine to get values.

  9. Listing 3.7 The Input Console.Read Routine

     1 Private Sub GetInputValues()
     2 Console.WriteLine()
     3 decStartingBalance = CDec( _
     4 GetValue("Initial Balance: "))
     5 dblAnnualInterest = CDbl(_
     6 GetValue("Annual Interest (e.g. for 5%, enter 5): "))
     7 decMonthlyDeposit = CDec(GetValue("Monthly deposit: "))
     8 iYears = CInt(GetValue("Years of investment: "))
     9 Console.WriteLine()
    10 End Sub
    11 
    12 Private Function GetValue(ByVal Prompt As String) As String
    13 Console.Write(Prompt)
    14 Return Console.ReadLine
    15 End Function

    Notice that the GetInputValues subroutine calls the GetValue function. This is an example of creating support routines. Rather than rewrite the code to prompt the user many times, pull the code out and create a procedure to perform the task. The resulting code in GetInputValues is therefore simplified.

  10. Write the routine that will display the output when it is calculated. Eventually, this might be displayed in a window, but for now, use the Console.WriteLine procedure, shown in Listing 3.8, to display the information. This procedure should take the value to display, and return nothing.

  11. Listing 3.8 The Output Console.WriteLine Routine

    1 Private Sub DisplayResults(ByVal Result As Double)
    2     Console.WriteLine()
    3     Console.WriteLine("If you start with {0:c}, ", decStartingBalance)
    4     Console.WriteLine(" and invest {0:c} per month", decMonthlyDeposit)
    5     Console.WriteLine(" for {0} years", iYears)
    6     Console.WriteLine(" at {0}% interest.", dblAnnualInterest)
    7     Console.WriteLine()
    8     Console.WriteLine("Your final balance would be: {0:c}", Result)
    9 End Sub

    This is a simple routine, consisting of a series of Console.WriteLine calls to display the entered values and the result of the calculation.

  12. Perform the FV calculation. This routine should take the four values as parameters, and return the result of the calculation. As it has a return value, this procedure is a function. Listing 3.9 shows the CalculateFV function.

  13. Listing 3.9 The CalculateFV Function

     1 Private Function CalculateFV(ByVal AnnualInterest As Double, _
     2    ByVal Years As Integer, _
     3    ByVal MonthlyDeposit As Double, _
     4    ByVal StartingBalance As Double) As Double
     5  'divide by 1200 to make it percent and per month
     6  Dim decMonthlyInterest As Double = CDec(AnnualInterest / 1200)
     7  Dim iMonths As Integer = Years * 12
     8  Dim decTemp As Double
     9  Dim decReturn As Double
    
    10  'we'll need this value in a couple of places
    11  decTemp = CDec((1 + decMonthlyInterest) ^ iMonths)
    12  decReturn = CDec(MonthlyDeposit * _
    13     ((decTemp - 1) / decMonthlyInterest) _
    14     + (StartingBalance * decTemp))
    
    15 Return decReturn
    
    16 End Function

    Just as with the GetInputValues, you could have pulled out the code that calculated the decTemp value. However, because you only need this calculation in this routine, and likely won't need it again, you don't.

    Listing 3.10 shows the full code for the sample application.

    Listing 3.10 The Complete Investment Calculator

     1 Module Invest
     2 
     3 Private dblAnnualInterest As Double = 0
     4 Private iYears As Integer = 0
     5 Private decStartingBalance As Double = 0
     6 Private decMonthlyDeposit As Double = 0 
     7 
     8 Sub Main()
     9 Dim decResult As Double
    10 'get input values
    11 GetInputValues()
    12 'calculate
    13 decResult = CalculateFV(dblAnnualInterest, _
    14 iYears, _
    15 decMonthlyDeposit, _
    16 decStartingBalance)
    17 'output result
    18 DisplayResults(decResult)
    19 End Sub
    20 
    21 Private Function CalculateFV(ByVal AnnualInterest As Double, _
    22 ByVal Years As Integer, _
    23 ByVal MonthlyDeposit As Double, _
    24 ByVal StartingBalance As Double) As Double
    25 'divide by 1200 to make it percent and per month
    26 Dim decMonthlyInterest As Double = CDec(AnnualInterest / 1200)
    27 Dim iMonths As Integer = Years * 12
    28 Dim decTemp As Double
    29 Dim decReturn As Double
    30 'we'll need this value in a couple of places
    31 decTemp = CDec((1 + decMonthlyInterest) ^ iMonths)
    32 decReturn = CDec(MonthlyDeposit * ((decTemp - 1) _
    33 / decMonthlyInterest) _
    34 + (StartingBalance * decTemp))
    35 Return decReturn
    36 End Function
    37 
    38 Private Function GetValue(ByVal Prompt As String) As String
    39 Console.Write(Prompt)
    40 Return Console.ReadLine
    41 End Function
    42 
    43 Private Sub GetInputValues()
    44 Console.WriteLine()
    45 decStartingBalance = CDec(GetValue("Initial Balance: "))
    46 dblAnnualInterest = _
    47 CDbl(GetValue("Annual Interest (for 5%, enter 5): "))
    48 decMonthlyDeposit = CDec(GetValue("Monthly deposit: "))
    49 iYears = CInt(GetValue("Years of investment: "))
    50 Console.WriteLine()
    51 End Sub
    52 
    53 Private Sub DisplayResults(ByVal Result As Double)
    54 Console.WriteLine()
    55 Console.WriteLine("If you start with {0:c}, ", decStartingBalance)
    56 Console.WriteLine(" and invest {0:c} per month", decMonthlyDeposit)
    57 Console.WriteLine("for {0} years", iYears)
    58 Console.WriteLine("at {0}% interest.", dblAnnualInterest)
    59 Console.WriteLine()
    60 Console.WriteLine("Your final balance would be: {0:c}", Result)
    61 End Sub
    62 End Module
  14. Run the application. The output should be similar to that shown at the beginning of this section. You can run the application from the IDE by clicking the Play button on the toolbar. However, it is likely that the window that pops up with the application will go away too quickly for you to see the answer. Instead, run the program from the command prompt by running the executable created.

You can try a frightening experiment with this calculator. Enter deposit values representing the money you would normally spend on a vice (lunch at work, cigarettes, electronic gadgets) each month. The resulting Future Value can often be disturbing.

  • + Share This
  • 🔖 Save To Your Account