Home > Articles > Programming > Windows Programming

  • Print
  • + Share This
This chapter is from the book

Using COM Objects in ASP.NET Pages

As in ASP pages, COM objects can be created in ASP.NET Web pages with the <object> tag. Using the <object> tag with a runat="server" attribute enables the COM object to be used in server-side script blocks. The <object> tag can contain a class identifier (CLSID) or programmatic identifier (ProgID) to identify the COM component to instantiate. The following code illustrates how to create an instance of a COM component using a CLSID:

<object id="MyObject" runat="server"
  classid="e2d9b696-86ce-45d3-8fc6-fb5b90230c11"
/>

And the following code illustrates how to create an instance of a COM component using a ProgID:

<object id="MyObject" runat="server"
  progid="Excel.Chart"
/>

These two COM-specific techniques use late binding and do not require Interop Assemblies in order to work. However, the ASP.NET <object> tag can also be used with a class attribute to instantiate .NET objects or COM objects described in an Interop Assembly. This can be used as follows:

<object id="recset" runat="server"
  class="ADODB.RecordsetClass, ADODB, Version=7.0.3300.0, Culture=neutral,  _PublicKeyToken=b03f5f7f11d50a3a"
/>

The class string contains an assembly-qualified class name, which has the ClassName, AssemblyName format. The assembly name could be just an assembly's simple name (such as ADODB or SpeechLib) if the assembly is not in the Global Assembly Cache. This is known as partial binding since the desired assembly isn't completely described. Assemblies that may reside in the Global Assembly Cache, however, must be referenced with their complete name, as shown in the preceding example. (Version policy could still be applied to cause a different version of the assembly to be loaded than the one specified.) As with the C++ Hello, World example, the Class suffix must be used with the class name.

Interop Assemblies used in ASP.NET pages should be placed with any other assemblies, such as in the site's \bin directory.

ASP.NET also provides several ways to create COM objects inside the server-side script block:

  • Using Server.CreateObject

  • Using Server.CreateObjectFromClsid

  • Using the new Operator

The Server.CreateObject method should be familiar to ASP programmers. Server.CreateObject is a method with one string parameter that enables you to create an object from its ProgID. The following code illustrates how to create an instance of a COM component using Server.CreateObject in Visual Basic .NET:

Dim connection As Object
connection = Server.CreateObject("ADODB.Connection")

The Server.CreateObjectFromClsid method is used just like Server.CreateObject but with a string representing a CLSID.

Again, these are two COM-specific mechanisms that use late binding. To take advantage of an Interop Assembly, you could use the new operator as in the Hello, World examples or use an overload of the Server.CreateObject method. This overload has a Type object parameter instead of a string. To use this method, we can obtain a Type object from a method such as System.Type.GetType, which is described in the "Common Interactions with COM Objects" section.

Tip

Using Server.CreateObject with a Type object obtained from Type.GetType or using the <object> tag with the class attribute is the preferred method of creating a COM object in an ASP.NET page. Besides giving you the massive performance benefits of early binding, it supports COM objects that rely on OnStartPage and OnEndPage notifications as given by classic ASP pages (whereas the New keyword does not).

Example: Using ADO in ASP.NET

To demonstrate the use of COM components in an ASP.NET Web page, this example uses one of the most widely used COM components in ASP—Microsoft ActiveX Data Objects, or ADO.

Tip

The functionality provided by ADO is available via ADO.NET, a set of data-related classes in the .NET Framework. Using these classes in the System.Data assembly is the recommended way to perform data access in an ASP.NET Web page.

However, because a learning curve is involved in switching to a new data-access model, you may prefer to stick with ADO. Thanks to COM Interoperability, you can continue to use these familiar COM objects when upgrading your Web site to use ASP.NET.

Listing 3.1 demonstrates using the ADO COM component in an ASP.NET page by declaring two ADO COM objects with the <object> tag.

Listing 3.1 Traditional ADO Can Be Used in an ASP.NET Page Using the Familiar <object> Tag

 1: <%@ Page aspcompat=true %>
 2: <%@ Import namespace="System.Data" %>
 3: <script language="VB" runat="server">
 4: Sub Page_Load(sender As Object, e As EventArgs)
 5:  Dim strConnection As String
 6:  Dim i As Integer
 7:
 8:  ' Connection string for the sample "pubs" database
 9:  strConnection = _ 
10:   "DRIVER={SQL Server};SERVER=(local);UID=sa;PWD=;DATABASE=pubs;"
11:
12:  Try
13:   ' Call a method on the page's connection object
14:   connection.Open(strConnection)
15:  Catch ex as Exception
16:   Response.Write("Unable to open connection to database. " + ex.Message)
17:  End Try
18:
19:  Try
20:   ' Set properties and call a method on the page's recordset object
21:   recordset.CursorType = 1 ' 1 = ADODB.CursorTypeEnum.adOpenKeyset
22:   recordset.LockType = 3  ' 3 = ADODB.LockTypeEnum.adLockOptimistic
23:   ' 2 = ADODB.CommandTypeEnum.adCmdTable
24:   recordset.Open("titles", connection, , , 2) 
25:  Catch ex as Exception
26:   Response.Write("Unable to open recordset. " + ex.Message)
27:  End Try
28:
29:  Dim table As DataTable
30:  Dim row As DataRow
31:
32:  ' Create a DataTable
33:  table = New DataTable()
34:
35:  ' Add the appropriate columns
36:  For i = 0 to recordset.Fields.Count - 1
37:   table.Columns.Add(New DataColumn(recordset.Fields(i).Name, _
38:    GetType(String)))
39:  Next
40:
41:  ' Scan through the recordset and add a row for each record
42:  Do While Not recordset.EOF
43:   row = table.NewRow()
44:
45:   ' Look at each field and add an entry to the row
46:   For i = 0 to recordset.Fields.Count - 1
47:    row(i) = recordset.Fields(i).Value.ToString()
48:   Next
49:
50:   ' Add the row to the DataTable
51:   table.Rows.Add(row)
52:
53:   recordset.MoveNext()
54:  Loop
55:
56:  ' Update the DataGrid control
57:  dataGrid1.DataSource = New DataView(table)
58:  dataGrid1.DataBind()
59:
60:  ' Cleanup
61:  recordset.Close()
62:  connection.Close()
63: End Sub
64: </script>
65:
66: <html><title>Using ADO in ASP.NET</title>
67:  <body>
68:   <form runat=server>
69:    <asp:DataGrid id="dataGrid1" runat="server"
70:     BorderColor="black"
71:     GridLines="Both"
72:     BackColor="#ffdddd"
73:    />
74:   </form>
75:   <object id="connection" runat="server"
76:    progid="ADODB.Connection"/>
77:   <object id="recordset" runat="server"
78:    progid="ADODB.Recordset"/>
79:  </body>
80: </html>

The <%@ Page aspcompat=true %> directive in Line 1 is explained in Chapter 6, "Advanced Topics for Using COM Components." The important part of Listing 3.1 is Lines 75–78, which declare the two COM objects used in the ASP.NET page via ProgIDs. The HTML portion of the page contains one control—the DataGrid control. This data grid will hold the information that we obtain using ADO.

Inside the Page_Load method, Lines 9–10 initialize a connection string for the sample database (pubs) in the local machine's SQL Server. You may need to adjust this string appropriately to run the example on your computer. Lines 21–24 use a few "magic numbers"—hard-coded values that represent various ADO enumeration values mentioned in the code's comments. If you use the Primary Interop Assembly for ADO, then you can reference the actually enum values instead.

After creating a new DataTable object in Line 33, we add the appropriate number of columns by looping through the Fields collection. On Line 37, each column added is given the name of the current field's Name property, and the type of the data held in each column is set to the type String. The Do While loop starting in Line 42 processes each record in the Recordset object. Once Recordset.EOF is true, we've gone through all the records. With each record, we create a new row (Line 43), add each of the record's fields to the row (Lines 46–48), and add the row to the table (Line 51). Each string added to a row is the current field's Value property. ToString is called on the Value property in Line 47, in case the data isn't already a string. In Lines 57–58, we associate the DataTable object with the page's DataGrid control and call DataBind to display the records. Finally, Lines 61–62 call Close on the two ADO objects to indicate that we're finished with them.

Figure 3.9 displays the output of Listing 3.1 as shown in a Web browser.

Figure 3.9 The output of Listing 3.1 when viewed in a Web browser.

Using COM+ Components

Just like COM components, COM+ components—formerly Microsoft Transaction Server (MTS) components—can be used in an ASP.NET application. However, due to differences between the ASP and ASP.NET security models, using COM+ components in an ASP.NET application might require changing their security settings.

If you get an error with a message such as "Permission denied" when attempting to use COM+ components, you should be able to solve the problem as follows:

  1. Open the Component Services explorer.

  2. Under the Component Services node, find the COM+ application you wish to use, right-click on it, and select Properties.

  3. Go to the Identity tab and change the account information to a brand new local machine account.

  4. At a command prompt, run DCOMCNFG.EXE, a tool that lets you configure DCOM settings (such as security) for your COM+ application.

  5. Go to the Default Security tab and click the Edit Default... button in the Default Access Permissions area.

  6. Add the new user created in Step 3.

  7. Restart Internet Information Services (IIS).

  • + Share This
  • 🔖 Save To Your Account