Home > Articles > Programming > Ruby

  • Print
  • + Share This
From the book

1.6 Interfaces and Classes

Object-oriented features are important for large projects, therefore introducing them by means of small examples is at high risk of looking goofy. Add to that a pressing desire to stay away from overused examples featuring shapes, animals, or employees, and we're faced with quite a pickle. Oh, and there's one more thing—small examples usually gloss over the issue of polymorphic object creation, which is important. Talk about writer's block! Fortunately, the real world provides a useful example in the form of a problem that's relatively small, yet has no satisfactory procedural solution. The code we'll discuss below is the rewrite of a small useful awk script that had grown well beyond the implicit limits set by its design. We will work together toward an object-oriented solution that is at the same time small, complete, and elegant.

Consider writing a small statistics program called stats with a simple modus operandi: stats takes the statistical functions to compute as command-line parameters, gathers the numbers to operate on via standard input as a whitespace-separated list, and prints the statistical results one per line. Here is a sample session:

$ echo 3 5 1.3 4 10 4.5 1 5 | stats Min Max Average
1
10
4.225
$ _

A quick-and-dirty script can perform such tasks no problem, yet the "dirty" tends to overshadow the "quick" as the number of statistical functions grows. So let's put together a better solution. For now, we start with the simplest statistical functions: minimum, maximum, and average. After figuring out an extensible design, the door is open to implementing more complex statistical functions.

A simple way to approach things is to just loop through the input and compute all needed statistics. This is not a scalable design because each time we need to add a new statistical function, we'd have to do surgery on existing code. The modifications will be nontrivial if we want to only do the computations asked for in the command line. Ideally, we'd confine each statistical function to one contiguous piece of code. That way, we can add new functionality to the program by simply appending new code—the Open-Closed principle [3] at its best.

Such an approach entails figuring out what all, or at least most, statistical functions have in common, to the end of manipulating them all from one place and in an uniform manner. Let's start by remarking that Min and Max take their input one number at a time, and have the result handy as soon as the input is finished. The final result is only one number. In addition, Average must do a post-processing step (divide the accumulated sum by the number of inputs). Moreover, each algorithm maintains its own state. When different computations obey a uniform interface and need to keep state, it makes sense to make them objects, and define a formal interface to manipulate any and all of them.

interface Stat {
   void accumulate(double x);
   void postprocess();
   double result();
}

An interface defines a required behavior as a set of functions. Of course, anyone claiming to implement the interface must define all functions as specified by their declarations. Speaking of implementation, let's see how we can define Min to obey Stat's iron fist:

class Min : Stat {
   private double min = double.max;
   void accumulate(double x) {
      if (x < min) {
         min = x;
      }
   }
   void postprocess() {} // nothing to do
   double result() {
      return min;
   }
}

Min is a class—a user-defined type that brings lots of object orientation goodies into D. Min manifestly implements Stat through the syntax class Min : Stat, and indeed defines Stat's three functions exactly with the same arguments and return types (otherwise the compiler would not have let Min get away with it). Min keeps only one private member variable min, which is the smallest value seen so far, and updates it inside accumulate. The initial value of Min is the largest possible number, such that the first input number will replace it.

Before defining more statistical functions, let's write a driver for our stats program that reads the command line parameters, creates the appropriate objects to do computations (such as Min when Min is passed in the command line) and uses the objects through the interface Stat.

import std.contracts, std.stdio;

void main(string[] args) {
   Stat[] stats;
   foreach (arg; args[1 .. $]) {
      auto newStat = cast(Stat) Object.factory("stat." ~ arg);
      enforce(newStat, "Invalid statistics function: " ~ arg);
      stats ~= newStat;
   }
   for (double x; readf(" %f ", &x) == 1; ) {
      foreach (s; stats) {
         s.accumulate(x);
      }
   }
   foreach (s; stats) {
      s.postprocess();
      writeln(s.result());
   }
}

This program does quite a lot but is only one mouthful. First off, main has a signature different from what we saw so far—it takes an array of strings. The D runtime support initializes the array from the command line parameters. The first loop initializes the stats array from args. Given that in D (as in C and C++) the first argument is the name of the program itself, we skip that first argument by taking the slice args[1 .. $]. We now hit the statement

auto newStat = cast(Stat) Object.factory("stat." ~ arg);

which is quite long, but, to quote a sitcom cliché, "I can explain." First, '~', when used as a binary operator, concatenates strings, so if the command-line argument was Max, the concatenation results in the string "stat.Max", which is passed to the function Object.factory. Object is the root of all class objects, and it defines the static method factory that takes a string, looks up a little database built during compilation, magically creates an object of the type named by the passed-in string, and returns it. If the class is not present, Object.factory returns null. For that call to succeed, all you need is have a class called Max defined somewhere in the same file. Creating an object given the name of its type is an important facility with many useful applications, so important in fact that some dynamic languages make it a central feature; languages with a more static approach to typing need to rely on runtime support (such as D or Java), or leave it to the programmer to devise a manual registration and discovery mechanism.

Why stat.Max and not just Max? D is quite serious about modularity so it does not have a global namespace in which anyone can put anything. Each symbol lives in a named module, and by default the name of the module is the base name of the source file (behavior that can be overridden by putting a directive module blah; at the top of the file). So given that our file is called stats.d, D reckons that every name defined in that file belongs to module stats.

There is one more hitch left. The static type of the just-obtained Min object is actually not Min. That sounds dumb, but it's justified by the fact that you could create any object by invoking Object.factory("whatever"), so the return type better be some common denominator of all possible object types—Object, that is. To get the appropriate handle on the newly-created object, we must make it into a Stat object, operation known as casting. In D, the expression cast(T) expr casts expression expr into type T. Casts involving class and interface types are always checked, so our code is foolproof.

Looking back, we notice that we've done a lot of solid work in main's first five lines. That was the hardest part, because the rest of the code writes itself. The second loop reads one number at a time (readf takes care of that) and calls accumulate for all statistical objects. The readf function returns the number of items read successfully according to the specified format (in our case, " %f " which means one floating-point number surrounded by any amount of whitespace). Finally, the program prints all results.

More Stats Implementations. Inheritance

Implementing Max is as trivial as implementing Min; aside from a slight change in accumulate, everything is exactly the same. Whenever a new task looks a lot like an old one, "interesting" and not "boring" is what should come to mind. A repetitive task is an opportunity for reuse, and rightly languages that can better exploit various flavors of similarity should rate higher on a certain quality scale. What we need to figure is the particular kind of similarity that Min and Max (and hopefully other statistical functions) enjoy. Thinking through, it looks like they both belong to the kind of statistical functions that (1) build their result incrementally, and (2) need only one number to characterize the result. Let's call this category of statistical functions, incremental functions.

abstract class IncrementalStat : Stat {
   protected double _result;
   void accumulate(double x);
   void postprocess() {}
   double result() {
      return _result;
   }
}

An abstract class can be seen as a partial commitment: it implements a number of methods, but not all, and as such cannot work standalone. The way to materialize an abstract class is to inherit it and complete its implementation. IncrementalStat takes care of Stat's boilerplate code but leaves accumulate to be implemented by the derived class. Here's how the new Min looks like:

class Min : IncrementalStat {
   this() {
      _result = double.max;
   }
   void accumulate(double x) {
      if (x < _result) {
         _result = x;
      }
   }
}

Class Min defined a constructor, too, in the form of a special function called this(), needed to initialize the result appropriately. Even with the constructor in place, the resulting code marks good savings from the initial state of affairs, particularly if we take into account the fact that many other statistical functions follow a similar pattern (e.g. sum, variance, average, standard deviation). Let's look at implementing average, because it's a great occasion to introduce a couple of more concepts:

class Average : IncrementalStat {
   private uint items = 0;
   this() {
      _result = 0;
   }
   void accumulate(double x) {
      _result += x;
      ++items;
   }
   override void postprocess() {
      if (items) {
         _result /= items;
      }
   }
}

First off, Average introduces one more member variable, items, which is initialized with zero through the syntax "= 0" (just to showcase initialization syntax, but redundant in this case because integral types are zero-initialized anyway as discussed on page 17). Second, Average defines a constructor that sets result to zero; this is because, unlike minimum or maximum, the average of zero numbers is defined to be zero. Although it might seem that initializing result with NaN just to overwrite it later with zero is needless busywork, optimizing away the so-called "dead assignment" is low-hanging fruit for any optimizer. Finally, Average overrides postprocess even though IncrementalStat already defined it. In D, by default, you can override (inherit and redefine) member functions of all classes, with the remark that you must specify override so as to avoid various accidents (e.g. failing to override due to a typo or a change in the base type, or overriding something by mistake). In C++ lingo, member functions are virtual by default. If you prepend final to a member function, that prohibits derived classes from overriding the function, effectively stopping the virtual mechanism.

  • + Share This
  • 🔖 Save To Your Account