Home > Articles > Home & Office Computing > Microsoft Applications

📄 Contents

  1. Variance Estimates
  2. The Noncentrality Parameter and the Probability Density Function
  • Print
  • + Share This
From the author of The Noncentrality Parameter and the Probability Density Function

The Noncentrality Parameter and the Probability Density Function

You can get a better sense of how the size of the noncentrality parameter affects the shape of the F distribution by using it to calculate the probability density function.

The probability density function, or PDF, returns the relative frequency of the value of a statistic. There is a PDF for various distributions—the most familiar are the normal distribution, the chi-square distribution, the t distribution, and the F distribution. You can use the PDF to return the Y-ordinate associated with the X-value of one of these statistics.

Determining the PDF

To obtain the PDF, set the Cumulative argument in the statistic's .DIST function to FALSE. See the following sections for examples.

Standard Normal Distribution

The height of the normal curve for a z-value of -0.5:

    =NORM.S.DIST(-.5,FALSE)

returns 0.352, the relative height of the standard normal curve for a z-value of -0.5. Setting the second, Cumulative argument to TRUE returns 0.309, the cumulative area under the normal curve to the left of a z-value of -0.5.

The t Distribution

The height of the t distribution at a t value of 1.45 with 15 degrees of freedom:

    =T.DIST(1.45,15,FALSE)

returns 0.137, the height of the t distribution with 15 degrees of freedom at a t value of 1.45. Setting the Cumulative argument to TRUE instead of FALSE returns 0.916, the probability of occurrence of all values up to 1.45 in the t distribution with 15 degrees of freedom.

The noncentral t distribution has the same shape as the central t distribution but is shifted to the left or the right of the central t distribution, which has a mean of zero.

Chi-square Distribution

The height of the chi-square distribution at a chi-square value of 3, with 4 degrees of freedom:

    =CHISQ.DIST(3,4,FALSE)

returns 0.167. Setting the third, Cumulative argument to TRUE returns 0.442, the total probability of all chi-square values up to 3, in a chi-square distribution with 4 degrees of freedom.

The noncentral chi-square distribution has a different shape than the central chi-square distribution.

The F distribution

The height of the central F distribution at an F value of 2.00 with 3 (numerator) and 45 (denominator) degrees of freedom:

    =F.DIST(2,3,45,FALSE)

returns 0.148. Setting the fourth, Cumulative argument to TRUE returns 0.872, the cumulative probability of all F values through 2, in a central F distribution with 3 and 45 degrees of freedom.

Like the chi-square distribution, the noncentral F distribution has a different shape than the central F distribution.

Determining the PDF for the Noncentral F Distribution

Although Excel's worksheet functions provide good support for the central chi-square and the central F distributions, they do not provide direct support for noncentral chi-square and F distributions. The remainder of this article discusses how to use Excel to determine the PDF for noncentral F distributions. The final article in this series shows how to determine the cumulative density function (CDF) for noncentral F distributions, so that you can determine the statistical power of an F test.

The workbook that accompanies this article contains a worksheet named Figure 3. See Figure 3.

Figure 3 Change any of the figures in cells B2:B4 to see their effect on the noncentral F distribution.

The central F distribution's shape is solely a function of the degrees of freedom for the numerator and for the denominator of the F ratio. The shape of the noncentral F distribution is a function of the noncentrality parameter, in addition to its degrees of freedom.

To see the changes to the shape of the noncentral F distribution on an Excel chart, change any of the three figures in cells B2:B4 on the worksheet.

As you change any of the three figures, the formulas for the PDF recalculate and the chart is re-drawn. The formulas in column E are array formulas and must be entered using Ctrl-Shift-Enter instead of simply pressing the Enter key. Here is the formula used in cell E2, which is copied and pasted down to cell E61:

=SUM((E^(-Lambda/2)*((Lambda/2)^(ROW(A$1:A$11)-
1)))/((EXP(GAMMALN(V_2/2)+GAMMALN(V_1/2+(ROW(A$1:A$11)-1))-
GAMMALN(V_2/2+(V_1/2+(ROW(A$1:A$11)-
1)))))*FACT((ROW(A$1:A$11)-
1)))*(V_1/V_2)^(V_1/2+(ROW(A$1:A$11)-
1))*(V_2/(V_2+V_1*D2))^((V_1+V_2)/2+(ROW(A$1:A$11)-
1))*D2^(V_1/2-1+(ROW(A$1:A$11)-1)))

Be sure to try setting the noncentrality parameter to a positive number very close to zero, such as 0.001. Doing so will result in a distribution very close to the central F distribution for your selected number of degrees of freedom for the numerator and for the denominator. Recall that when the noncentrality parameter is zero, the result is a central F distribution.

Also, be sure to notice that the shape of the noncentral F distribution shifts to the right as the noncentrality parameter moves away from zero. As that happens, more and more of the area under the curve moves to the right of the critical value for alpha. And the result is to increase the statistical power of the F test.

What’s Next

The final article in this series continues the discussion of the noncentral F distribution. The focus shifts from the distribution's PDF to its cumulative density function, which is your best measure of the test's statistical power.

  • + Share This
  • 🔖 Save To Your Account